Mfcttrf

Hello fellow Emacs Lisp enthusiasts!

I've encountered problem that I am even embarrassed to describe. It is very clear how to use condition-case from all the docs and examples that I can find online, but still even the simplest example won't work for me.

Here is a minimal code snippet:

(defun foo ()
 (signal 'test-signal '(1 2 3)))

(condition-case nil
 (foo)
 (test-signal nil))

I use Emacs 26.1, but encounter the same behaviour on other versions as well.

Thank you for any help!

Your error symbol test-signal is not defined. C-h f signal says:

An error symbol is a symbol with an error-conditions property
that is a list of condition names.

Let's check this for some standard error symbols and the test-signal

(get 'error 'error-conditions)
;; => (error)

(get 'args-out-of-range 'error-conditions)
;; => (args-out-of-range error)

(get 'test-signal 'error-conditions)
;; => nil

To define an error symbol, use define-error, e.g.,

(define-error 'test-signal "My error for testing")

then you can handle the error in condition-case, e.g.,

(condition-case err
 (signal 'test-signal '(1 2 3))
 (test-signal (error-message-string err)))
;; => "My error for testing: 1, 2, 3"

You need to define a symbol as an error to get Emacs to recognize it:

(define-error 'test-signal
 "Test signal" 'error)

(defun foo ()
 (signal 'test-signal '(1 2 3)))

(condition-case nil
 (foo)
 (error nil))

From (elisp) Error Symbols:

-- Function: define-error name message &optional parent

In order for a symbol to be an error symbol, it must be defined
with define-error which takes a parent condition (defaults to
error). This parent defines the conditions that this kind of
error belongs to. The transitive set of parents always includes
the error symbol itself, and the symbol error. Because quitting
is not considered an error, the set of parents of quit is just
(quit).